Sensor ultrasónico HC-SR04 y Arduino – Guía completa

El código que mide la distancia es más o menos el mismo que el ejemplo básico. Aquí, en lugar de imprimir los resultados en el monitor serie, los imprimimos en la pantalla LCD. Si necesita más detalles sobre cómo usar y conectar una pantalla LCD con Arduino, puede consultar mi tutorial particular.

/*
  Ultrasonic Sensor HC-SR04 and Arduino Tutorial

  by Dejan Nedelkovski,
  www.HowToMechatronics.com

*/
#include <LiquidCrystal.h> // includes the LiquidCrystal Library
LiquidCrystal lcd(1, 2, 4, 5, 6, 7); // Creates an LCD object. Parameters: (rs, enable, d4, d5, d6, d7)
const int trigPin = 9;
const int echoPin = 10;
long duration;
int distanceCm, distanceInch;
void setup() {
  lcd.begin(16, 2); // Initializes the interface to the LCD screen, and specifies the dimensions (width and height) of the display
  pinMode(trigPin, OUTPUT);
  pinMode(echoPin, INPUT);
}
void loop() {
  digitalWrite(trigPin, LOW);
  delayMicroseconds(2);
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin, LOW);
  duration = pulseIn(echoPin, HIGH);
  distanceCm = duration * 0.034 / 2;
  distanceInch = duration * 0.0133 / 2;
  lcd.setCursor(0, 0); // Sets the location at which subsequent text written to the LCD will be displayed
  lcd.print("Distance: "); // Prints string "Distance" on the LCD
  lcd.print(distanceCm); // Prints the distance value from the sensor
  lcd.print(" cm");
  delay(10);
  lcd.setCursor(0, 1);
  lcd.print("Distance: ");
  lcd.print(distanceInch);
  lcd.print(" inch");
  delay(10);
}Code language: Arduino (arduino)

Código de ejemplo usando la biblioteca NewPing

En realidad, hay una forma mejor y más simple de programar el Arduino para medir la distancia usando el sensor ultrasónico HC-SR04, y eso es usando la biblioteca NewPing.

En el código explicado anteriormente, activamos manualmente el sensor y medimos la duración del pulso de la señal recibida. Luego, de acuerdo con esos resultados, calculamos la distancia en función de ellos. Usando la biblioteca NewPing podemos obtener la distancia con solo una línea de código.

Aquí hay un código de ejemplo:

#include <NewPing.h>

#define TRIGGER_PIN  9
#define ECHO_PIN     10
#define MAX_DISTANCE 400 // Maximum distance we want to measure (in centimeters).


NewPing sonar(TRIGGER_PIN, ECHO_PIN, MAX_DISTANCE); // NewPing setup of pins and maximum distance.

void setup() {
  Serial.begin(9600);
}

void loop() {
  delay(50);                    // Wait 50ms between pings (about 20 pings/sec). 29ms should be the shortest delay between pings.

  int distance = sonar.ping_cm(); // Send ping, get distance in cm and print result (0 = outside set distance range)

  Serial.print("Distance: ");
  Serial.print(distance);
  Serial.println("cm");
}Code language: Arduino (arduino)

Es mucho más sencillo que el ejemplo anterior. Simplemente usamos la llamada ping_cm() en el objeto de sonda NewPing y obtenemos la distancia en centímetros. Si queremos la distancia en pulgadas podemos usar ping_in() en su lugar.

La biblioteca también tiene algunas otras características útiles. Por ejemplo, con ping_median(iterations [, max_cm_distance]) método, podemos obtener resultados más precisos, ya que devuelve una mediana, o el valor medio de varias mediciones. Con las iteraciones parámetro establecemos el número de muestras que el programa tomará para calcular el valor medio. El valor predeterminado es 5 iteraciones. El ping_median() devuelve la duración del pulso recibido en microsegundos.

No obstante, para obtener más información y detalles, puede consultar la página wiki de NewPing.

Mejora de la precisión del sensor de distancia HC-SR04 con el sensor de temperatura DHT22

El sensor HC-SR04 es bastante preciso, pero como su funcionamiento depende de la velocidad del sonido, para obtener resultados más precisos también debemos tener en cuenta la temperatura del aire. La velocidad del sonido puede cambiar significativamente a medida que cambia la temperatura del aire. Por ejemplo, a 20 °C, la velocidad del sonido es de unos 340 m/s, pero a -20 °C la velocidad del sonido es de unos 315 m/s. La humedad relativa también afecta la velocidad.

Entonces, si usamos este sensor para medir distancias a varias temperaturas, deberíamos implementar una compensación de temperatura, y podemos hacerlo con la siguiente fórmula:

Velocidad =331,4 + 0,6 x Temperatura + 0,0124 x Humedad_relativa

He aquí un ejemplo:

Junto con el sensor ultrasónico HC-SR04, utilizaremos el sensor DHT11/DHT22 para medir la temperatura y la humedad del ambiente y ajustar la velocidad del valor del sonido en consecuencia.

Código Arduino

/*
  Example made by Dejan, How To Mechatronics,
  https://howtomechatronics.com/

*/

#include <NewPing.h>  // https://bitbucket.org/teckel12/arduino-new-ping/wiki/Home
#include "dht.h"      // https://github.com/RobTillaart/DHTlib

#define TRIGGER_PIN  9
#define ECHO_PIN     10
#define MAX_DISTANCE 400
#define dht22 5 // DHT22 temperature and humidity sensor

NewPing sonar(TRIGGER_PIN, ECHO_PIN, MAX_DISTANCE);
dht DHT; // Creats a DHT object

int readDHT, temp, hum;
float speedOfSound, distance, duration;

void setup() {
  Serial.begin(9600);
}

void loop() {
  delay(100);

  // Read temperature and humidity from DHT22 sensor
  readDHT = DHT.read22(dht22); // Reads the data from the sensor
  temp = DHT.temperature; // Gets the values of the temperature
  hum = DHT.humidity; // Gets the values of the humidity


  speedOfSound = 331.4 + (0.6 * temp) + (0.0124 * hum); // Calculate speed of sound in m/s

  duration = sonar.ping_median(10); // 10 interations - returns duration in microseconds
  duration = duration/1000000; // Convert mircroseconds to seconds
  distance = (speedOfSound * duration)/2;
  distance = distance * 100; // meters to centimeters

  Serial.print("Distance: ");
  Serial.print(distance);
  Serial.println("cm");

}Code language: Arduino (arduino)

Entonces, primero leemos los valores de temperatura y humedad del sensor DHT22 y luego usamos esos valores para calcular la velocidad del sonido. Luego obtenemos la duración del viaje de la onda de sonido en microsegundos, los convertimos a segundos y calculamos la distancia desde el sensor hasta los objetos en centímetros.

HC-SR04 Dimensiones y modelo 3D

Hice un modelo 3D del sensor ultrasónico HC-SR04 en caso de que necesite uno al realizar su próximo proyecto con él. Puede descargarlo desde el siguiente enlace.

Puede encontrar y descargar este modelo 3D en Thangs.

Estas son las dimensiones del sensor HC-SR04:

Tenga en cuenta que a veces pueden diferir un poco según el fabricante.

Conclusión

Entonces, hemos cubierto prácticamente todo lo que necesitamos saber sobre el uso del sensor ultrasónico HC-SR04 con Arduino. Es un gran sensor para muchos proyectos de electrónica de bricolaje en los que necesitamos una medición de distancia sin contacto, detección de presencia u objetos, nivelación o posición de algo, etc.

Ya mencioné los proyectos que he realizado con este sensor al principio del post. Aquí hay algunos otros proyectos geniales que usan el sensor HC-SR04 y Arduino:

• Bote de basura con sensor de movimiento automático sin contacto
• Control de luz inteligente mediante gestos con las manos
• Mini levitación acústica
• Robot que evita obstáculos

Espero que hayas disfrutado este tutorial y hayas aprendido algo nuevo. No dude en hacer cualquier pregunta en la sección de comentarios a continuación y no olvide consultar mi colección completa de más de 30 proyectos Arduino.

Cómo controlar servomotores con Arduino – Guía completa Explicación del código G | Lista de los comandos de código G más importantes