Cómo controlar los LED direccionables individualmente WS2812B usando Arduino

Dependiendo de la casilla de verificación seleccionada, enviamos un primer carácter o marcador diferente que ayuda cuando se recibe el texto en el Arduino. Lo mismo sucede cuando cambiamos la posición del control deslizante, se envía un valor de 10 a 100 al Arduino en forma de texto, con el marcador "3" al frente.

Puede descargar la aplicación de Android a continuación, así como el archivo del proyecto MIT App Inventor:

DIY_Reactive_LED_Table_Control

Archivo de proyecto de inventor de la aplicación MIT DIY_Reactive_LED_Table_Control

Aquí está el código de Arduino:

#include <SoftwareSerial.h>

#include "FastLED.h"

#define NUM_LEDS 45
#define LED_PIN 2
#define COLOR_ORDER GRB

CRGB leds[NUM_LEDS];

SoftwareSerial Bluetooth(53, 52); // Arduino(RX, TX) - Bluetooth (TX, RX)

// Initial background color 
int backR = 100;
int backG = 50;
int backB = 10;

// Initial reactive color 
int reactiveR = 10;
int reactiveG = 50;
int reactiveB = 100;

int brightness = 50; // Initial brightness

String dataIn = "";

void setup() {
  FastLED.addLeds<WS2812, LED_PIN, COLOR_ORDER>(leds, NUM_LEDS);
  FastLED.setBrightness(brightness);
  Serial.begin(38400);
  Bluetooth.begin(38400); // Default baud rate of the Bluetooth module

  for (int pinNo = 0 + 3; pinNo <= 45 + 3; pinNo++) {
    pinMode(pinNo, INPUT);
  }
}

void loop() {
  if (Bluetooth.available() > 0) {
    dataIn = Bluetooth.readString();
    delay(20);
    if (dataIn.startsWith("1")) {
      delay(10);
      String stringR = dataIn.substring(dataIn.indexOf("R") + 1, dataIn.indexOf("G"));
      reactiveR = stringR.toInt();
      String stringG = dataIn.substring(dataIn.indexOf("G") + 1, dataIn.indexOf("B"));
      reactiveG = stringG.toInt();
      String stringB = dataIn.substring(dataIn.indexOf("B") + 1, dataIn.indexOf("E"));
      reactiveB = stringB.toInt();
    }
    else if (dataIn.startsWith("2")) {
      String stringR = dataIn.substring(dataIn.indexOf("R") + 1, dataIn.indexOf("G"));
      backR = stringR.toInt();
      String stringG = dataIn.substring(dataIn.indexOf("G") + 1, dataIn.indexOf("B"));
      backG = stringG.toInt();
      String stringB = dataIn.substring(dataIn.indexOf("B") + 1, dataIn.indexOf("E"));
      backB = stringB.toInt();
    }
    else if (dataIn.startsWith("3")) {
      String stringBrightness = dataIn.substring(dataIn.indexOf("3") + 1, dataIn.length());
      brightness = stringBrightness.toInt();
      FastLED.setBrightness(brightness);
    }
  }

  for (int pinNo = 0; pinNo <= NUM_LEDS-1; pinNo++) {
    leds[pinNo] = CRGB( backR, backG, backB);
    if ( digitalRead(pinNo + 3) == LOW ) {
      leds[pinNo] = CRGB( reactiveR, reactiveG, reactiveB);
    }
  }
  FastLED.show();
  delay(20);
}Code language: Arduino (arduino)

Descripción: Primero debemos definir la comunicación serial entre el Arduino y el módulo Bluetooth HC-05, o los pines a los que se conecta el módulo. En la sección de configuración, debemos establecer la velocidad en baudios a la que funciona este módulo. Luego, en el ciclo principal, usando la función Bluetooth.available(), verificamos si hay datos entrantes desde el teléfono inteligente. Si eso es cierto, usando la función Bluetooth.readString() recibimos los datos como una cadena. Luego, usando la función .startsWith(), verificamos el primer carácter o el marcador y de esa manera sabemos si queremos cambiar el color reactivo, el fondo o el brillo.

Usando la función .substring() extraemos los valores rojo, verde y azul del texto recibido y los convertimos en números enteros. Estos valores luego se usan en el bucle "for" a continuación, que establece el color y enciende los LED como se explicó anteriormente. De la misma manera ajustamos el brillo de los LEDs.

Así que eso es todo por este tutorial. No dude en hacer cualquier pregunta en la sección de comentarios a continuación.