Robot hexápodo de hormiga Arduino

Recuerda que la entrada principal a la PCB debe ser de 5V.

Entonces ahora podemos insertar los componentes electrónicos entre las dos placas. Una vez más, está un poco apretado, pero aún podemos colocar todo. Primero va la batería, que la aseguré con una cinta, y encima va el Arduino junto con el PCB que hicimos. A continuación podemos conectar el transceptor NRF24L01 o solo el módulo Bluetooth según el tipo de comunicación que vayamos a utilizar. También inserté un LED para indicar cuándo la batería necesita recargarse, o en caso de que el voltaje caiga por debajo de 11V voltios. Por último, necesitamos conectar todos los servos a los pines del servo. Mientras hace esto, asegúrese de anotar a qué número de pin conectó cada servo. Después de conectar todos los servos, simplemente podemos colocar la cubierta curva en la placa superior y ya hemos terminado con este proyecto.

Código Arduino Hexapod

Lo que queda por hacer en este video es ver cómo funciona el programa Arduino. Como el código es un poco más largo, para una mejor comprensión, publicaré el código fuente del programa en secciones con descripción para cada sección. Y al final de este artículo publicaré el código fuente completo.

Entonces, para controlar los servos, usaremos la biblioteca Servo básica y, para la comunicación Bluetooth, también debemos incluir la biblioteca SoftwareSerial. Primero, debemos definir todos los objetos servo, así como algunas variables necesarias para el programa a continuación.

#include <Servo.h>
#include <SoftwareSerial.h>

#define trigPin 7
#define echoPin 6
#define ledB 10

SoftwareSerial Bluetooth(12, 9); // Arduino(RX, TX) - HC-05 Bluetooth (TX, RX)

// Create servo object
Servo s24;
Servo s23;
Servo s22;Code language: Arduino (arduino)

En la sección de configuración, debemos inicializar la comunicación Bluetooth, los modos de pin para el sensor ultrasónico, el LED y también definir los pines a los que se conectan los servos.

void setup() {
  Serial.begin(38400);
  Bluetooth.begin(38400); // Default baud rate of the Bluetooth module
  Bluetooth.setTimeout(1);
  delay(20);
  pinMode(trigPin, OUTPUT); // Sets the trigPin as an Output
  pinMode(echoPin, INPUT); // Sets the echoPin as an Input
  pinMode(ledB, OUTPUT);
  // Head
  s15.attach(36, 600, 2400);
  s14.attach(35, 600, 2400);
  s13.attach(34, 600, 2400); //grip
  // Tail
  s5.attach(26, 600, 2400); // Tail
  // Leg 4
  s10.attach(31, 600, 2400);
  s11.attach(32, 600, 2400);
  s12.attach(33, 600, 2400); //rot
  // Leg 5
  s7.attach(28, 600, 2400);
  s8.attach(29, 600, 2400);
  s9.attach(30, 600, 2400); //rot
  // Leg 6
  s1.attach(22, 600, 2400);
  s2.attach(23, 600, 2400);
  s3.attach(24, 600, 2400); //rot
  // Leg 1
  s18.attach(39, 600, 2400);
  s17.attach(38, 600, 2400);
  s16.attach(37, 600, 2400); //rot
  // Leg 2
  s21.attach(42, 600, 2400);
  s20.attach(41, 600, 2400);
  s19.attach(40, 600, 2400); //rot
  // Leg 3
  s24.attach(45, 600, 2400);
  s23.attach(44, 600, 2400);
  s22.attach(43, 600, 2400); //rotCode language: Arduino (arduino)

Luego usando las funciones write() movemos los servos a su posición inicial. Aquí es donde podemos calibrar nuestros servos. Tenga en cuenta que no podrá configurar cada servo en la posición exacta al ensamblar el robot, pero aquí podemos hacer ajustes y averiguar nuestros valores iniciales y desde allí podemos programar el movimiento del robot.

// == Move to initial position
  // Head
  s15.write(72);
  s14.write(50);
  s13.write(90); // Grip
  
  s5.write(65); // Tail
  
  // Leg 4
  s10.write(65);
  s11.write(35);
  s12.write(40);
  // Leg 5
  s7.write(80);
  s8.write(50);
  s9.write(25);
  // Leg 6
  s1.write(90);
  s2.write(45);
  s3.write(60);

  // Leg 1
  s18.write(60);
  s17.write(90);
  s16.write(100);
  // Leg 2
  s21.write(50);
  s20.write(85);
  s19.write(75);
  // Leg 3
  s24.write(50);
  s23.write(80);
  s22.write(80);Code language: Arduino (arduino)

Cuando se trata de programar un movimiento de hexápodo, hay varias formas de hacerlo, como usar una cinemática directa o inversa. Estos métodos incluyen algunas matemáticas serias en las que la posición de cada articulación se calcula en función de las entradas para la posición final deseada del cuerpo. Sin embargo, decidí hacerlo un poco menos complicado porque de todos modos los servos que estoy usando no son lo suficientemente buenos para tal tarea. Eso es porque mis servos son la versión barata del servo MG996R. No tienen el par correcto y no siempre se posicionan exactamente en la posición deseada.

Así que echemos un vistazo a cómo hice que el hexápodo caminara. Hice una función personalizada separada para mover cada pierna. Un ciclo de pierna incluye dos fases, llamadas swing y stance. En la fase de balanceo, la pierna se mueve desde una posición inicial a una posición final a través del aire, mientras que en la fase de apoyo, la pierna se mueve desde la posición final de regreso a la posición inicial con el efector final de la pierna tocando el suelo. De esta manera el cuerpo del hexápodo avanzará.

Entonces programo manualmente las posiciones de cada servo para lograr estos movimientos usando el bucle principal y algunos contadores.

void moveLeg1() {
  // Swign phase - move leg though air - from initial to final position
  // Rise the leg
  if (i1L1 <= 10) {
    s18.write(60 - i1L1 * 2);
    s17.write(90 - i1L1 * 3);
    i1L1++;
  }
  // Rotate the leg
  if (i2L1 <= 30) {
    s16.write(100 - i2L1);
    i2L1++;

  }
  // Move back to touch the ground
  if (i2L1 > 20 & i3L1 <= 10) {
    s18.write(40 + i3L1 * 2);
    s17.write(60 + i3L1 * 3);
    i3L1++;
  }
  // Stance phase - move leg while touching the ground
  // Rotate back to initial position
  if (i2L1 >= 30) {
    s16.write(70 + i4L1);
    i4L1++;
    l1status = HIGH;
  }
  // Reset the counters for repeating the process
  if (i4L1 >= 30) {
    i1L1 = 0;
    i2L1 = 0;
    i3L1 = 0;
    i4L1 = 0;
    i5L1 = 0;
  }
  // Each iteration or step is executed in the main loop section where there is also a delay time for controlling the speed of movement
}Code language: Arduino (arduino)

Primero, los dos servos externos elevan la pata y el tercer servo conectado al cuerpo comienza a girar en una dirección particular. Cuando el tercer servo está 10 pasos antes de que deje de girar, comenzamos a mover los dos servos exteriores hacia atrás en la misma posición para tocar el suelo. Esto completa la fase de balanceo, o la pierna movida desde su posición inicial a la final. Luego giramos hacia atrás el tercer servo desde la posición final a la inicial, y eso completa la fase de postura. Después de que el tramo ejecuta un ciclo, los contadores se reinician y el tramo repetirá el ciclo una y otra vez. Cada iteración o paso se ejecuta en la sección de bucle principal donde también hay un tiempo de retraso que controla la velocidad de los servos. Hice funciones como esta para todas las demás piernas, así como algunas funciones adicionales para mover las piernas en dirección opuesta para lograr movimientos hacia atrás, hacia la izquierda y hacia la derecha. De manera similar, usando contadores para llevar la cuenta de los pasos, programé el resto de las funciones, como mover la cabeza, mover la cola, las mandíbulas, etc.

Entonces, por ejemplo, si queremos mover el robot hacia adelante, debemos llamar a las seis funciones personalizadas moveLeg() que se repetirán constantemente en el ciclo principal.

// Move forward
  if (m == 2) {
    moveLeg1();
    moveLeg3();
    moveLeg5();
    if (l1status == HIGH) {
      moveLeg2();
      moveLeg4();
      moveLeg6();
    }
  }Code language: Arduino (arduino)

Puede notar que las 3 patas están desplazadas, por lo que cuando la pierna número 1, 3 y 5 están en fase de balanceo, las otras tres patas, 2, 4 y 6 están en fase de apoyo. En caso de que queramos movernos a la izquierda, llamamos a las funciones moveLeft() apropiadas.

Estos comandos en realidad provienen del módulo Bluetooth o de la aplicación de Android personalizada de nuestro teléfono inteligente.

// Check for incoming data
  if (Bluetooth.available() > 0) {
    dataIn = Bluetooth.read();  // Read the dataCode language: Arduino (arduino)

Aplicación Arduino Ant Robot para Android

Echemos un vistazo a la aplicación ahora y veamos qué tipo de datos está enviando realmente al Arduino. Creé la aplicación usando la aplicación en línea MIT App Inventor y así es como funciona.

Entonces, los gráficos de la aplicación son en realidad imágenes que hice y coloqué como botones. En la parte inferior tenemos un control deslizante para controlar la velocidad del robot y en la parte superior tenemos los botones para conectar con el módulo Bluetooth.

Echemos un vistazo al programa o los bloques detrás de la aplicación.

Entonces, por ejemplo, si hacemos clic en el botón Adelante, se ejecutarán los bloques en la declaración "si". Eso significa que enviaremos el número 2 al Arduino y eso ejecutará el conjunto de funciones de avance. Al mismo tiempo podemos notar que cambiamos la imagen del botón a la otra versión resaltada de la misma imagen. Si volvemos a pulsar el mismo botón, ahora se ejecutarán los bloques de la sentencia “else” y eso enviará el número 0 al Arduino que reiniciará todos los contadores y moverá el robot a sus posiciones iniciales. También retrocedemos la imagen inicial de ese botón. Así que utilicé el mismo principio para todos los demás botones.

Aquí hay un archivo de descarga del proyecto MIT App Inventor anterior, así como la aplicación de Android lista para instalar en su teléfono inteligente:

Echemos un vistazo a dos funciones más en el programa Arduino y ese es el monitor de voltaje de la batería y el sensor ultrasónico.

// Monitor the battery voltage
    int sensorValue = analogRead(A3);
    float voltage = sensorValue * (5.00 / 1023.00) * 2.9; // Convert the reading values from 5v to suitable 12V i
    Serial.println(voltage);
    // If voltage is below 11V turn on the LED
    if (voltage < 11) {
      digitalWrite(ledB, HIGH);
    }
    else {
      digitalWrite(ledB, LOW);
    }Code language: Arduino (arduino)

Entonces, si el voltaje de la batería es inferior a 11 voltios, encenderemos el LED y si el sensor ultrasónico detecta un objeto a menos de 40 cm, el robot se preparará para un ataque.

// Get the distance from the ultrasonic sensor
    if (getDistance() > 40) {
      att = 0;
    }
    if (getDistance() <= 40) {
      att = 1;
      dataIn = 99;
    }Code language: Arduino (arduino)

En caso de que ya no haya un objeto enfrente, descartará el ataque y si el objeto aún está presente y más cerca de la cabeza, el robot atacará.

// If there is an object in front of the sensor prepare for attack
  if (att == 1) {
    prepareAttack();
    if (aStatus == HIGH) {
      while (a == 0) {
        delay(2000);
        a = 1;
      }
      if (getDistance() > 30) {
        att = 2;
        a = 0;
        aStatus = LOW;
        initialPosHead();
      }
      if (getDistance() < 30) {
        att = 3;
        a = 0;
        aStatus = LOW;
        initialPosHead();
      }
    }
  }
  // If there is no longer object in front, dismiss the attack
  if (att == 2) {
    dismissAttack();
    if (aStatus == HIGH) {
      dataIn = 0;
      att = 0;
    }
  }
  // If there is closer to the sensor attack
  if (att == 3) {
    attack();
    if (attStatus == HIGH) {
      while (aa == 0) {
        delay(2000);
        aa = 1;
      } attStatus = LOW;
    }
    if (aStatus == HIGH) {
      while (a == 0) {
        delay(2000);
        a = 1;
      }
      dataIn = 0;
      att = 0;
      initialPosHead();
    }
  }Code language: Arduino (arduino)

Así que eso es prácticamente todo para este video.

Aquí puede descargar el código completo para este proyecto Arduino Hexapod:

Tenga en cuenta que si decide construir este proyecto, debe estar preparado para enfrentar algunos desafíos. El mayor problema para mí fue el bajo rendimiento de los servos que utilicé. Espero que hayas disfrutado este video y hayas aprendido algo nuevo. No dude en hacer cualquier pregunta en la sección de comentarios a continuación y consulte mi Colección de proyectos de Arduino.

Transmisor DIY Arduino RC Dobladora de alambre 3D Arduino