Cómo rastrear la orientación con Arduino y el acelerómetro ADXL345

Entonces, estamos usando el mismo código, que envía los valores de Roll y Pitch a través del puerto serial. Aquí está el código completo de Arduino:

/*
    Arduino and ADXL345 Accelerometer - 3D Visualization Example 
     by Dejan, https://howtomechatronics.com
*/
#include <Wire.h>  // Wire library - used for I2C communication

int ADXL345 = 0x53; // The ADXL345 sensor I2C address

float X_out, Y_out, Z_out;  // Outputs
float roll,pitch,rollF,pitchF=0;

void setup() {
  Serial.begin(9600); // Initiate serial communication for printing the results on the Serial monitor
 
  Wire.begin(); // Initiate the Wire library
  // Set ADXL345 in measuring mode
  Wire.beginTransmission(ADXL345); // Start communicating with the device
  Wire.write(0x2D); // Access/ talk to POWER_CTL Register - 0x2D
  // Enable measurement
  Wire.write(8); // Bit D3 High for measuring enable (8dec -> 0000 1000 binary)
  Wire.endTransmission();
  delay(10);

  //Off-set Calibration
  //X-axis
  Wire.beginTransmission(ADXL345);
  Wire.write(0x1E);
  Wire.write(1);
  Wire.endTransmission();
  delay(10);
  //Y-axis
  Wire.beginTransmission(ADXL345);
  Wire.write(0x1F);
  Wire.write(-2);
  Wire.endTransmission();
  delay(10);

  //Z-axis
  Wire.beginTransmission(ADXL345);
  Wire.write(0x20);
  Wire.write(-9);
  Wire.endTransmission();
  delay(10);
}

void loop() {
  // === Read acceleromter data === //
  Wire.beginTransmission(ADXL345);
  Wire.write(0x32); // Start with register 0x32 (ACCEL_XOUT_H)
  Wire.endTransmission(false);
  Wire.requestFrom(ADXL345, 6, true); // Read 6 registers total, each axis value is stored in 2 registers
  X_out = ( Wire.read() | Wire.read() << 8); // X-axis value
  X_out = X_out / 256; //For a range of +-2g, we need to divide the raw values by 256, according to the datasheet
  Y_out = ( Wire.read() | Wire.read() << 8); // Y-axis value
  Y_out = Y_out / 256;
  Z_out = ( Wire.read() | Wire.read() << 8); // Z-axis value
  Z_out = Z_out / 256;

  // Calculate Roll and Pitch (rotation around X-axis, rotation around Y-axis)
  roll = atan(Y_out / sqrt(pow(X_out, 2) + pow(Z_out, 2))) * 180 / PI;
  pitch = atan(-1 * X_out / sqrt(pow(Y_out, 2) + pow(Z_out, 2))) * 180 / PI;

  // Low-pass filter
  rollF = 0.94 * rollF + 0.06 * roll;
  pitchF = 0.94 * pitchF + 0.06 * pitch;

  Serial.print(rollF);
  Serial.print("/");
  Serial.println(pitchF);
}Code language: Arduino (arduino)

Ahora, en el entorno de desarrollo de procesamiento, necesitamos recibir estos valores y usarlos para rotar el objeto 3D que crearemos. Aquí está el código de procesamiento completo:

/*
    Arduino and ADXL345 Accelerometer - 3D Visualization Example 
     by Dejan, https://howtomechatronics.com
*/

import processing.serial.*;
import java.awt.event.KeyEvent;
import java.io.IOException;

Serial myPort;

String data="";
float roll, pitch;

void setup() {
  size (960, 640, P3D);
  myPort = new Serial(this, "COM8", 9600); // starts the serial communication
  myPort.bufferUntil('\n');
}

void draw() {
  translate(width/2, height/2, 0);
  background(33);
  textSize(22);
  text("Roll: " + int(roll) + "     Pitch: " + int(pitch), -100, 265);

  // Rotate the object
  rotateX(radians(roll));
  rotateZ(radians(-pitch));
  
  // 3D 0bject
  textSize(30);  
  fill(0, 76, 153);
  box (386, 40, 200); // Draw box
  textSize(25);
  fill(255, 255, 255);
  text("www.HowToMechatronics.com", -183, 10, 101);

  //delay(10);
  //println("ypr:\t" + angleX + "\t" + angleY); // Print the values to check whether we are getting proper values
}

// Read data from the Serial Port
void serialEvent (Serial myPort) { 
  // reads the data from the Serial Port up to the character '.' and puts it into the String variable "data".
  data = myPort.readStringUntil('\n');

  // if you got any bytes other than the linefeed:
  if (data != null) {
    data = trim(data);
    // split the string at "/"
    String items[] = split(data, '/');
    if (items.length > 1) {

      //--- Roll,Pitch in degrees
      roll = float(items[0]);
      pitch = float(items[1]);
    }
  }
}Code language: Arduino (arduino)

Descripción: Entonces, aquí, debemos incluir la biblioteca en serie, definir el puerto en serie y la velocidad en baudios que debe coincidir con la velocidad en baudios del boceto Arduino cargado. Luego leemos los datos entrantes y los colocamos en las variables de balanceo y cabeceo apropiadas. En el ciclo de dibujo principal, usamos estos valores para rotar el objeto 3D, y en este caso es un cuadro simple con un color particular y un texto en él.

Si ejecutamos el boceto, aparecerá el objeto 3D y seguirá la orientación del sensor del acelerómetro. Podemos notar aquí que el objeto en realidad está un poco inestable y eso se debe a que el acelerómetro captura no solo la fuerza gravitatoria, sino también pequeñas fuerzas generadas por los movimientos de nuestra mano. Para obtener un resultado más suave, podemos usar un filtro de paso bajo simple. Aquí implementé un filtro de este tipo en el código Arduino, que toma el 94 % del estado anterior y agrega el 6 % del estado o ángulo actual.

// Low-pass filter
  rollF = 0.94 * rollF + 0.06 * roll;
  pitchF = 0.94 * pitchF + 0.06 * pitch;Code language: Arduino (arduino)

Con este filtro, podemos notar que el objeto se mueve mucho más suave ahora, pero también hay un efecto secundario y es una respuesta más lenta. También podemos notar que nos falta el Yaw, o la rotación alrededor del eje Z. Usando solo los datos del acelerómetro de 3 ejes, no podemos calcular la Yaw.

Para hacer eso y mejorar el rendimiento general de nuestro sensor de seguimiento de orientación, necesitamos incluir un sensor adicional, un giroscopio, y fusionar sus datos con el acelerómetro.

Entonces, podemos usar el acelerómetro ADXL345 en combinación con un sensor de giroscopio, o usar la IMU MPU6050 que tiene un acelerómetro de 3 ejes y un giroscopio de 3 ejes integrados en un solo chip. Puede encontrar un tutorial más detallado sobre este sensor en mi próximo video.

Espero que hayas disfrutado este tutorial y hayas aprendido algo nuevo. Siéntase libre de hacer cualquier pregunta en la sección de comentarios a continuación y no olvide consultar mi colección de proyectos Arduino.

Tutorial de acelerómetro y giroscopio Arduino y MPU6050 Tutorial de control de motores sin escobillas Arduino | ESC | BLDC