Regalo de San Valentín: Contador DIY de Días Juntos

Componentes y materiales

Sobre el proyecto

En septiembre de 2017, al iniciar mi segundo año de universidad, conocí a una chica maravillosa. Nos mudamos juntos con sus amigos y terminamos compartiendo una planta de la casa, solo nosotros dos. Empezamos a hablar, nos hicimos mejores amigos y, tras un par de meses, comenzamos a salir. Nuestra fecha oficial fue el 10 de diciembre de 2017 (formato UK).

Casi un año después, buscaba una idea original para nuestro aniversario. Quería regalarle algo hecho por mí, aplicando lo que estudiaba (electrónica). Se me ocurrió crear un contador que mostrara los días que llevábamos juntos, integrándolo en un marco de fotos con una imagen nuestra.

Si has llegado aquí buscando una idea para tu aniversario o simplemente por curiosidad, este es un proyecto divertido y gratificante. Te explicaré todo paso a paso para que puedas hacerlo tú mismo.

La parte más compleja es el código. He preparado una plantilla que, al compilarse y subirse, muestra mi fecha y la de mi novia, pero incluye comentarios para que puedas introducir fácilmente la tuya propia.

¡Disfruta construyéndolo!

Código

DaysCounter.ino (C/C++)

Necesitarás:

• Arduino IDE
• Librería RTC (archivo ZIP)
• Librería Seven Segment (archivo ZIP)

Guarda ambas librerías en la carpeta libraries de tu instalación de Arduino IDE. Luego, en el IDE: Sketch → Include Library → Add .ZIP Library.

Para ajustar la fecha: En la línea 7, dentro del paréntesis (2017, 12, 9, 0, 0, 0), modifica los tres primeros números (año, mes, día) por la fecha en que empezasteis a salir. Ejemplo: 2014, 4, 6.

#include <RTClib.h>
#include <SevSeg.h>

SevSeg sevseg;
RTC_DS3231 rtc;
DateTime dtBegin(2017, 12, 9, 0, 0, 0); // ˇAJUSTA TU FECHA AQUÍ!
TimeSpan tsPassed;

void showInfo(const DateTime& dt) {
  Serial.print("NOW:");
  Serial.print(dt.year(), DEC); Serial.print('/');
  Serial.print(dt.month(), DEC); Serial.print('/');
  Serial.print(dt.day(), DEC); Serial.print(' ');
  Serial.print(dt.hour(), DEC); Serial.print(':');
  Serial.print(dt.minute(), DEC); Serial.print(':');
  Serial.print(dt.second(), DEC); Serial.print("\tPASSED:");
  Serial.print(tsPassed.days(), DEC); Serial.print(' ');
  Serial.print(tsPassed.hours(), DEC); Serial.print(':');
  Serial.print(tsPassed.minutes(), DEC); Serial.print(':');
  Serial.print(tsPassed.seconds(), DEC); Serial.println();
}

void delayWithUpdate(uint32_t parDelay) {
  uint32_t started = millis();
  while (millis() < started + parDelay) {
    sevseg.refreshDisplay();
  }
}

void setup() {
  Serial.begin(9600);
  Serial.println(__TIME__);

  if (!rtc.begin()) {
    Serial.println("No se encontró RTC");
    while (1); // Bucle infinito si falla
  }
  delay(1000);

  // Para ajustar la hora del RTC (descomenta, sube, comenta, sube de nuevo):
  // rtc.adjust(DateTime(F(__DATE__), F(__TIME__)));

  byte numDigits = 4;
  byte digitPins[] = {7, 8, 9, 10};
  byte segmentPins[] = {2, 3, 4, 5, 11, 12, 13, 6};
  bool resistorsOnSegments = false;
  byte hardwareConfig = COMMON_CATHODE;
  bool updateWithDelays = false;
  bool leadingZeros = false;
  bool disableDecPoint = true;

  sevseg.begin(hardwareConfig, numDigits, digitPins, segmentPins,
               resistorsOnSegments, updateWithDelays, leadingZeros, disableDecPoint);
  sevseg.setBrightness(100);

  // Test rápido de la pantalla
  sevseg.setNumber(1234, 1); delayWithUpdate(1000);
  sevseg.setNumber(8888, 1); delayWithUpdate(1000);
}

void loop() {
  sevseg.refreshDisplay();
  DateTime now = rtc.now();
  tsPassed = now - dtBegin;

  static uint32_t nextReportMillis = 0;
  static uint16_t prevDaysPassed = 0;

  if (tsPassed.days() != prevDaysPassed) {
    prevDaysPassed = tsPassed.days();
    sevseg.setNumber(prevDaysPassed, 0);
  }

  if (millis() > nextReportMillis) {
    showInfo(now);
    nextReportMillis = millis() + 5000;
  }
}

Esquemáticos

Puedes generar el esquema automáticamente en Circuito.io:

1. Copia y pega el enlace en el navegador.
2. Haz clic en "Add components".
3. Añade: RTC DS3231 y 7 segment display 20mm (genérico).
4. Sigue el diagrama y conecta cada pin con cables jumper.