nRF24L01 - Cómo funciona, interfaz Arduino, circuitos, códigos

Puede obtener los componentes necesarios para este ejemplo desde los siguientes enlaces:

• Módulo transceptor NRF24L01…………
• Placa Arduino…………………………………….
• Módulo de palanca de mando ……………………………….
• Servomotor …………………………………….
• Pulsador ……………………………………..
• LED ……………………………………………………

código fuente nRF24L01

Aquí están los dos códigos y su descripción a continuación.

Código del transmisor

/*
* Arduino Wireless Communication Tutorial
*     Example 2 - Transmitter Code
*                
* by Dejan Nedelkovski, www.HowToMechatronics.com
* 
* Library: TMRh20/RF24, https://github.com/tmrh20/RF24/
*/

#include <SPI.h>
#include <nRF24L01.h>
#include <RF24.h>

#define led 12

RF24 radio(7, 8); // CE, CSN
const byte addresses[][6] = {"00001", "00002"};
boolean buttonState = 0;

void setup() {
  pinMode(12, OUTPUT);
  radio.begin();
  radio.openWritingPipe(addresses[1]); // 00002
  radio.openReadingPipe(1, addresses[0]); // 00001
  radio.setPALevel(RF24_PA_MIN);
}

void loop() {
  delay(5);

  radio.stopListening();
  int potValue = analogRead(A0);
  int angleValue = map(potValue, 0, 1023, 0, 180);
  radio.write(&angleValue, sizeof(angleValue));

  delay(5);
  radio.startListening();
  while (!radio.available());
  radio.read(&buttonState, sizeof(buttonState));
  if (buttonState == HIGH) {
    digitalWrite(led, HIGH);
  }
  else {
    digitalWrite(led, LOW);
  }
}Code language: Arduino (arduino)

Código del receptor

/*
* Arduino Wireless Communication Tutorial
*     Example 2 - Receiver Code
*                
* by Dejan Nedelkovski, www.HowToMechatronics.com
* 
* Library: TMRh20/RF24, https://github.com/tmrh20/RF24/
*/

#include <SPI.h>
#include <nRF24L01.h>
#include <RF24.h>
#include <Servo.h>

#define button 4

RF24 radio(7, 8); // CE, CSN
const byte addresses[][6] = {"00001", "00002"};
Servo myServo;
boolean buttonState = 0;

void setup() {
  pinMode(button, INPUT);
  myServo.attach(5);
  radio.begin();
  radio.openWritingPipe(addresses[0]); // 00001
  radio.openReadingPipe(1, addresses[1]); // 00002
  radio.setPALevel(RF24_PA_MIN);
}

void loop() {
  delay(5);
  radio.startListening();
  if ( radio.available()) {
    while (radio.available()) {
      int angleV = 0;
      radio.read(&angleV, sizeof(angleV));
      myServo.write(angleV);
    }
    delay(5);
    radio.stopListening();
    buttonState = digitalRead(button);
    radio.write(&buttonState, sizeof(buttonState));
  }
}Code language: Arduino (arduino)

Lo que es diferente aquí del ejemplo anterior es que necesitamos crear dos conductos o direcciones para la comunicación bidireccional.

const byte addresses[][6] = {"00001", "00002"};Code language: Arduino (arduino)

En la sección de configuración, debemos definir ambas tuberías y tenga en cuenta que la dirección de escritura en el primer Arduino debe ser la dirección de lectura en el segundo Arduino, y viceversa, la dirección de lectura en el primer Arduino debe ser la dirección de escritura en el segundo Arduino.

// at the Transmitter
radio.openWritingPipe(addresses[1]); // 00001
radio.openReadingPipe(1, addresses[0]); // 00002Code language: Arduino (arduino)

// at the Receiver
radio.openWritingPipe(addresses[0]); // 00002
radio.openReadingPipe(1, addresses[1]); // 00001Code language: Arduino (arduino)

En la sección de bucle usando la función radio.stopListening() configuramos el primer Arduino como transmisor, leemos y mapeamos el valor del Joystick de 0 a 180, y usando la función radio.write() enviamos los datos al receptor.

radio.stopListening();
int potValue = analogRead(A0);
int angleValue = map(potValue, 0, 1023, 0, 180);
radio.write(&angleValue, sizeof(angleValue));Code language: Arduino (arduino)

Por otro lado, usando la función radio.startListening() configuramos el segundo Arduino como receptor y verificamos si hay datos disponibles. Mientras haya datos disponibles, los leeremos, los guardaremos en la variable "angleV" y luego usaremos ese valor para rotar el servomotor.

radio.startListening();
  if ( radio.available()) {
    while (radio.available()) {
      int angleV = 0;
      radio.read(&angleV, sizeof(angleV));
      myServo.write(angleV);
    }Code language: Arduino (arduino)

A continuación, en el transmisor, configuramos el primer Arduino como receptor y con un ciclo "while" vacío esperamos que el segundo Arduino envíe los datos, y esos son los datos para el estado del botón, ya sea que esté presionado o no. Si se presiona el botón, el LED se encenderá. Entonces, este proceso se repite constantemente y ambas placas Arduino envían y reciben datos constantemente.

Ejemplo 3:envío de múltiples variables en un solo paquete

Echemos un vistazo a un código de ejemplo más usando los módulos NRF24L01. Todo sigue igual que en los ejemplos anteriores, excepto por la forma en que estructuramos y enviamos la fecha.

Código del transmisor

/*
  Arduino Wireless Communication Tutorial
      Example 1 - Transmitter Code

  by Dejan Nedelkovski, www.HowToMechatronics.com

  Library: TMRh20/RF24, https://github.com/tmrh20/RF24/
*/

#include <SPI.h>
#include <nRF24L01.h>
#include <RF24.h>

RF24 radio(7, 8); // CE, CSN

const byte address[6] = "00001";

// Max size of this struct is 32 bytes - NRF24L01 buffer limit
struct Data_Package {
  byte a = 0;
  byte b = 125;
  byte c = 255;
  int d = 1024;
  float e = 3.141592;
  String f = "Test";
};

Data_Package data; // Create a variable with the above structure

void setup() {
  radio.begin();
  radio.openWritingPipe(address);
  radio.setPALevel(RF24_PA_MIN);
  radio.stopListening();
}

void loop() {
  // Send the whole data from the structure to the receiver
  radio.write(&data, sizeof(Data_Package));
  delay(500);
}Code language: Arduino (arduino)

Entonces, podemos crear una estructura que en realidad es una colección de varios tipos de variables.

// Max size of this struct is 32 bytes - NRF24L01 buffer limit
struct Data_Package {
  byte a = 0;
  byte b = 125;
  byte c = 255;
  int d = 1024;
  float e = 3.141592;
  String f = "Test";
};

Data_Package data; // Create a variable with the above structureCode language: Arduino (arduino)

Debemos tener en cuenta que el tamaño máximo de esta estructura de datos puede ser de 32 bytes. Aquí podemos ver que incluí tres variables tipo byte, una variable entera (4 bytes), una variable flotante (4 bytes) y una cadena que contiene cuatro caracteres (4 bytes). Eso es un total de 15 bytes.

Código del receptor

/*
  Arduino Wireless Communication Tutorial
        Example 1 - Receiver Code

  by Dejan Nedelkovski, www.HowToMechatronics.com

  Library: TMRh20/RF24, https://github.com/tmrh20/RF24/
*/

#include <SPI.h>
#include <nRF24L01.h>
#include <RF24.h>

RF24 radio(7, 8); // CE, CSN

const byte address[6] = "00001";

// Max size of this struct is 32 bytes - NRF24L01 buffer limit
struct Data_Package {
  byte a = 0;
  byte b = 125;
  byte c = 255;
  int d = 1024;
  float e = 3.141592;
  String f = "Test";
};

Data_Package data; //Create a variable with the above structure

void setup() {
  Serial.begin(9600);
  radio.begin();
  radio.openReadingPipe(0, address);
  radio.setPALevel(RF24_PA_MIN);
  radio.startListening();
}

void loop() {
  // Check whether there is data to be received
  if (radio.available()) {
    radio.read(&data, sizeof(Data_Package)); // Read the whole data and store it into the 'data' structure
  }
  Serial.print("a: ");
  Serial.print(data.a);
  Serial.print(" b: ");
  Serial.print(data.b);
  Serial.print(" c: ");
  Serial.print(data.c);
  Serial.print(" d: ");
  Serial.print(data.d);
  Serial.print(" e: ");
  Serial.print(data.e);
  Serial.print(" f: ");
  Serial.println(data.f);
}Code language: Arduino (arduino)

En el lado del receptor, tenemos que definir los mismos datos de estructura para poder recibir los datos entrantes. Para probar si la comunicación inalámbrica funciona correctamente, imprimí cada variable en el monitor serie.

Conclusión

El módulo NRF24L01 es una excelente opción cuando necesita comunicación inalámbrica para su proyecto Arduino. Ya he usado este módulo en muchos de mis proyectos Arduino.

Aquí listaré todos mis proyectos en los que he usado estos módulos.

• Control inalámbrico de Arduino Robot Car usando los módulos transceptores HC-05 Bluetooth, NRF24L01 y HC-12
• Proyecto de estación meteorológica inalámbrica Arduino
• Transmisor DIY Arduino RC
• Robot hexápodo de hormiga Arduino
• Aerodeslizador RC basado en Arduino DIY
• Robot de ruedas Arduino Mecanum
• Receptor DIY Arduino RC para modelos RC y proyectos Arduino
• Avión RC Arduino | 100% bricolaje

Cada uno de estos proyectos/tutoriales tiene una explicación detallada de cómo usar el módulo NRF24L01, incluidos diagramas de circuitos, implementación de código mejorada para una mejor comunicación, etc.

Mi proyecto favorito es este transmisor Arduino RC diseñado a medida. En realidad, es un controlador RC de 14 canales que se puede usar para controlar prácticamente cualquier proyecto Arduino.

Eso es todo por este tutorial, espero que lo hayan disfrutado y aprendido algo nuevo. Como siempre, no dude en hacer cualquier pregunta en la sección de comentarios a continuación.

Tercer ojo para los ciegos Arduino 16×2 LCD Tutorial – Todo lo que necesitas saber